NAMESPACE := "infra"
APP_NAME := "registry"

status:
    @echo "=== Pods ==="
    @kubectl get pods -n {{NAMESPACE}} | grep registry
    @echo ""
    @echo "=== Service ==="
    @kubectl get svc -n {{NAMESPACE}} docker-registry-service
    @echo ""
    @echo "=== PVC ==="
    @kubectl get pvc -n {{NAMESPACE}} docker-registry-pvc
    @echo ""
    @echo "=== ArgoCD Status ==="
    @kubectl get application {{APP_NAME}} -n cicd -o jsonpath='Sync: {.status.sync.status}, Health: {.status.health.status}' 2>/dev/null && echo ""

logs lines="100":
    kubectl logs -n {{NAMESPACE}} -l app=docker-registry --tail={{lines}} -f

port-forward port="5000":
    @echo "Forwarding docker registry to localhost:{{port}}"
    kubectl port-forward -n {{NAMESPACE}} svc/docker-registry-service {{port}}:5000

sync:
    @echo "Triggering ArgoCD sync..."
    @kubectl annotate application {{APP_NAME}} -n cicd argocd.argoproj.io/refresh=normal --overwrite
    @sleep 2
    @kubectl get application {{APP_NAME}} -n cicd -o jsonpath='Sync: {.status.sync.status}, Health: {.status.health.status}' && echo ""

argocd-status:
    argocd app get {{APP_NAME}} --core

restart:
    @echo "Restarting docker registry..."
    kubectl rollout restart -n {{NAMESPACE}} deployment/docker-registry